|==== dum_as_f for use on EZServer

|==== FilterSets.mac
|==== Use this macro to save or load your filter configuration on the
|==== Options Window.  Sometimes filters seem to revert to the default
|==== settings, this allows you to apply your saved filter settings
|==== to a character by having MQ2 iterate through each setting and
|==== choosing your desired setting for that filter.

|==== /echo savefilters NameToSaveAs will write the current settings to an INI file.

|==== /echo loadfilters NameToLoad will load the settings for NameToLoad from the INI
|==== and iterate through them and apply the corresponding setting.

        #Event Help "[MQ2] filtersets help"
        #Event SaveNewFilterSet "[MQ2] savefilters #1#"
        #Event ReadFromIni      "[MQ2] loadfilters #1#"
       
|==== Sub Main
        Sub Main
                /echo FilterSets macro is running...please [/echo filtersets help] for help information.
                /call CreateIni
                :LoopLogic
                        /doevents
                /goto :LoopLogic
        /return
|==== End Sub Main

|==== Sub CreateIni
        Sub CreateIni
                /declare thisFilterSet          string  outer
                /varset thisFilterSet ${Me}
               
                /if (${Ini[FilterSets.ini].Length}) /return
               
                /echo No Ini file found, creating a new one with ${Me} as default filter setting
                /call FilterSetLoop
        /return
|==== End Sub CreateIni

|==== Event_SaveNewFilterSet
        Sub Event_SaveNewFilterSet(Line, SetName)
                /if (${SetName.Length}) {
                        /echo Attempting to save filter set ${SetName}
                        /varset thisFilterSet ${SetName}
                        /call FilterSetLoop
                } else {
                        /echo You need to supply a name for a filter set before you can save it, try again.
                }
        /return
|==== End Event_SaveNewFilterSet

|==== Sub FilterSetLoop
        Sub FilterSetLoop
                /declare i int local
                /for i 1 to ${Window[OptionsWindow].Child[OFP_FilterList].Items}
                        /notify OptionsChatPage OFP_FilterList listselect ${Window[OptionsWindow].Child[OFP_FilterList].List[=${Window[OptionsWindow].Child[OFP_FilterList].List[${i}]}]}
                        /echo Setting ${Window[OptionsWindow].Child[OFP_FilterList].List[${i}]} to: ${Window[OptionsChatPage].Child[OFP_FilterList].List[${i},2]}
                        /ini "FilterSets.ini" "${thisFilterSet}" "${i}. ${Window[OptionsWindow].Child[OFP_FilterList].List[${i}]}" "${Window[OptionsChatPage].Child[OFP_FilterList].List[${i},2]}"
                        /delay 3
                /next i
                /echo [ ${thisFilterSet} ] filter set has been created and/or updated in the FilterSets.ini file
        /return
|==== End Sub FilterSetLoop

|==== Sub Event_ReadFromIni
        Sub Event_ReadFromIni(Line, FilterSetName)
                /echo Reading from Ini file
                /if (!${Defined[filterDescription]}) /declare filterDescription string  outer
                /declare i                                              int     local
                /declare thisDescription                string  local
                /declare descriptionSubstring   string  local
                /declare filterSetting                  string  local
                /declare loadFilterSet                  string  local   ${FilterSetName}
               
                /if (${FilterSetName.Length}) {
                        /varset filterDescription ${Ini[FilterSets.ini,"${loadFilterSet}"]}
                        /echo Accessing values from FilterSet ${loadFilterSet}
                        /for i 1 to ${Window[OptionsWindow].Child[OFP_FilterList].Items}
                                /varset thisDescription ${filterDescription.Arg[${i},|]}
                                /varset descriptionSubstring ${thisDescription.Mid[4,${Math.Calc[${thisDescription.Length}-3]}]}
                                /notify OptionsChatPage OFP_FilterList listselect ${Window[OptionsChatPage].Child[OFP_FilterList].List[=${descriptionSubstring}]}
                                /varset filterSetting ${Ini[FilterSets.ini,${loadFilterSet},${thisDescription}]}
                                /notify OptionsChatPage OFP_FilterComboBox listselect ${Window[OptionsChatPage].Child[OFP_FilterComboBox].List[=${filterSetting}]}
                                /echo Setting ${descriptionSubstring} to ${filterSetting}
                                /delay 3
                        /next i
                } else {
                        /echo You need to supply a name for a filter set before you can load it, try again.
                }
        /return
|==== End Sub Event_ReadFromIni

|==== Sub Event_Help
        Sub Event_Help
                /echo Macro will build a default filter set based on current filter values if no INI file is found.
                /echo [/echo savefilters NameToSaveAs] is the syntax for saving current settings to the INI, NametoSaveAs can be whatever you want to name the filter set.
                /echo
                /echo [/echo loadfilters NameToLoad] to load a filter set named NameToLoad from the INI
        /return
|==== End Sub Event_Help